REM  =====================================================================
REM  ||  Hier die drei Parameter...                                     ||
REM  ||  - Wurzel-Verzeichnis                                           ||
REM  ||  - Aufteilungs-Typ                                              ||
REM  ||  - Virtuelles privates Laufwerk                                 ||
REM  ||  ... wählen                                                     ||
REM  =====================================================================

REM  Hier das Wurzel-Verzeichnis von PC CADDIE eintragen
SET PCCHOME=C:\PCCADDIE

REM  Hier kann man entweder 
REM    - USER für die User-bezogene Aufteilung oder
REM    - COMPUTER für die Computer-bezogene Einteilung wählen
SET PCCTYPE=COMPUTER

REM  Hier wird das virtuelle private Laufwerk angegeben:
SET PCCPRVDIR=L:


REM  =====================================================================
REM  ||                  Ab hier nichts mehr ändern                     ||
REM  =====================================================================

IF %PCCTYPE%==USER GOTO PCC_USER
GOTO PCC_COMPUTER


:PCC_USER
REM Dies ist die Variante für User-bezogene Verknüpfungen:
SET PCCSUBDIR=%USERNAME%
GOTO PCC_START


:PCC_COMPUTER
REM Dies ist die Variante für Computer-bezogene Verknüpfungen:
SET PCCSUBDIR=%CLIENTNAME%
GOTO PCC_START


:PCC_START
REM Erstmal prüfen, ob es den Ordner für den Clientname überhaupt gibt
IF EXIST %PCCHOME%\TSC\%PCCSUBDIR%\PCCADDIE GOTO PCC_DIROK

REM Unter-Verzeichnis exisiert nicht => also auf DEFAULT setzen
SET PCCSUBDIR=DEFAULT

IF EXIST %PCCHOME%\TSC\%PCCSUBDIR%\PCCADDIE GOTO PCC_DIROK

REM Default-Dir existiert nicht
md %PCCHOME%\TSC\%PCCSUBDIR%
md %PCCHOME%\TSC\%PCCSUBDIR%\PCCADDIE
xcopy %PCCHOME%\USER_1 %PCCHOME%\TSC\%PCCSUBDIR%\PCCADDIE\USER_1 /s /e /v /i /d 

GOTO PCC_DIROK


:PCC_DIROK
SUBST %PCCPRVDIR% /D
SUBST %PCCPRVDIR% %PCCHOME%\TSC\%PCCSUBDIR%
GOTO READY


:READY
%PCCPRVDIR%
CD %PCCPRVDIR%\PCCADDIE\USER_1\PROGRAMM
START PCC_WIN.EXE %1